Orsdxy

how to simulate the following partial differential equation using Low level FEM in mathematica?

D[u[x,y], x] - D[u[x,y], y]=x Sin[x y] - y Sin[x y]

the answer is Cos[x y]
added)

region is [-1,1] for x and [-1,1] for y.
Boundary Condition is u[-1,y]=Cos[-y]

here is my tried code:

delta[x_, a_] := Block[{}, If[x == a, 1, 0]]; 

mesh = Table[PDF[NormalDistribution[a, z], x]*

     PDF[NormalDistribution[b, z], y], {a, -1, 1, 0.1}, 

    {b, -1, 1, 0.1}]; 

mesh = Flatten[mesh]; 

cofs = Table[ToExpression[StringJoin[ToString[c], 

      ToString[a], ToString[b]]], {a, 0, 20}, {b, 0, 20}]; 

cofs = Flatten[cofs]; 

weights = Table[delta[x, a]*delta[y, b], {a, -1, 1, 0.05}, 

    {b, -1, 1, 0.05}]; 

weights = Flatten[weights]; 

expr = cofs . mesh; 

residual = D[expr, x] - D[expr, y] - (x*Sin[x*y] - 

     y*Sin[x*y]); 

integrated = residual*Plus @@ weights; 

toMinimize = Plus @@ Flatten[Table[integrated, 

      {x, -1, 1, 0.1}, {y, -1, 1, 0.1}]]; 

toMinimize = toMinimize^2; 

cofs = Append[cofs, z]; 

conds = Abs[(expr /. {x -> 0, y -> 0}) - 1]; 

opt = NMinimize[{toMinimize + conds}, cofs, 

    Method -> {Automatic, PerformanceGoal -> "Speed"}]; 

u = expr /. Last[opt]; 

ListPlot3D[Table[u*Plus @@ weights /. {x -> a, y -> b}, 

   {a, -1, 1, 0.1}, {b, -1, 1, 0.1}]]

I am not a 100% sure I understand your question, here is what I think could help you.

The finite element method is, strictly speaking, not a method to solve PDEs. What it does it takes a continuous PDE and converts it to an approximate equivalent matrix and vector. The matrix and vector are discrete representations of the PDE. When you solve this set of equations you will get an approximate solution to the PDE.

We set up an equation:

Needs["NDSolve`FEM`"]

{state} = 

  NDSolve`ProcessEquations[{Laplacian[u[x, y], {x, y}] == 1, 

    DirichletCondition[u[x, y] == 0, True]}, u, {x, 0, 1}, {y, 0, 1}, 

   Method -> {"FiniteElement"}];

Now we extract some data from the NDSolve state data object.

femdata = state["FiniteElementData"]

femdata["Properties"]

methodData = femdata["FEMMethodData"];

bcData = femdata["BoundaryConditionData"];

pdeData = femdata["PDECoefficientData"];

variableData = state["VariableData"];

solutionData = state["SolutionData"][[1]];

If you do not want to / can not use NDSolve`ProcessEquations you may need to look at InitializePDECoefficients and such functions.

If you look at pdeData, that now contains the coefficients of the equations given in NDSolve:

pdeData["All"]



{{{{1}}, {{{{0}, {0}}}}}, {{{{{-1, 

      0}, {0, -1}}}}, {{{{0}, {0}}}}, {{{{0, 

      0}}}}, {{0}}}, {{{0}}}, {{{0}}}}

Now, the finite element method is applied. This converts the continuous PDE into a system of discrete matrices:

discretePDE = DiscretizePDE[pdeData, methodData, solutionData]

{load, stiffness, damping, mass} = discretePDE["SystemMatrices"]

You can look at the matrices:

MatrixPlot[stiffness]

The same conversion is done for the boundary conditions:

discreteBCs = 

  DiscretizeBoundaryConditions[bcData, methodData, solutionData];

All the finite element method does is done now. The rest is linear algebra.

We now put the discrete boundary conditions into the discrete matrices:

DeployBoundaryConditions[{load, stiffness}, discreteBCs]

Solve:

solution = LinearSolve[stiffness, load];

Generate an Interpolating function:

mesh = methodData["ElementMesh"];

ifun = ElementMeshInterpolation[{mesh}, solution]

And visualize:

Plot3D[ifun[x, y], {x, y} [Element] mesh]

Hope this helps a bit.